Keyboard Message

Σε αυτό το παράδειγμα, το πάτημα οποιουδήποτε πλήκτρου αντιστοιχεί σε αποστολή μιας συμβολοσειράς κειμένου προς τον υπολογιστή. Θεωρητικά, αυτό λειτουργεί ως η είσοδος του πληκτρολογίου. Επίσης, αυτή η συμβολοσειρά αναφέρει για το πόσες φορές έχει πατηθεί ένα πλήκτρο. Όλα αυτά μπορούν να ειδωθούν σε οποιοδήποτε επεξεργαστή κειμένου.

Αποσαφήνιση: Να έχετε υπόψη σας ότι όταν χρησιμοποιείτε την εντολή Keyboard.print(), τότε το Arduino θα πάρει τον έλεγχο του πληκτρολογίου σας. Έτσι, πρώτα από όλα, βεβαιωθείτε ότι δεν θα χάσετε τον έλεγχο του υπολογιστή σας κατά την εκτέλεση κώδικα που εμπεριέχει αυτήν την συνάρτηση. Αυτό μπορεί να πραγματοποιηθεί αν δημιουργήσετε ένα αξιόπιστο σύστημα ελέγχου, προτού να καλέσετε την συνάρτηση Keyboard.print(). Ο παρακάτω κώδικας περιλαμβάνει έναν πιεστικό διακόπτη, ο οποίος λειτουργεί σαν ένας διακόπτης εναλλαγής. Επομένως, πατώντας αυτόν τον διακόπτη, θα μπορείτε να ρυθμίζετε για το ποιος έχει τον έλεγχο του πληκτρολογίου σας.

Απαιτούμενος εξοπλισμός

– Πλακέτα του Arduino Leonardo, Micro ή Due.
– Στιγμιαίο μπουτόν.
– Αντίσταση των 10k ohm.
– Breadboard.

Απαιτούμενο λογισμικό

Οποιοσδήποτε επεξεργαστής κειμένου.

Κύκλωμα

Συνδέστε το ένα άκρο του μπουτόν με τον ακροδέκτη 4 του Arduino σας. Ενώ, συνδέστε το άλλο άκρο με την τροφοδοσία 5V. Χρησιμοποιείστε την αντίστασή σας σαν μια αντίσταση καθόδου. Κατά αυτόν τον τρόπο, θα παρέχετε την απαιτούμενη γείωση. Συγκεκριμένα, αυτό πραγματοποιείτε εάν συνδέσετε τον ακροδέκτη 4 με την γείωση.

Αποσυνδέστε το καλώδιο του USB, αφού πρώτα έχετε προγραμματίσει την πλακέτα σας. Στην συνέχεια, ανοίξτε έναν επεξεργαστή κειμένου και τοποθετήστε τον δρομέα κειμένου στην περιοχή της πληκτρολόγησης. Συνδέστε ξανά τον υπολογιστή με την πλακέτα μέσω του καλωδίου USB. Έτσι, το πάτημα ενός κουμπιού θα εμφανίζεται στο έγγραφό σας.

Σχηματικά

 

 

 

 

 

 

 

 

 

Κώδικας

/*
 Keyboard Message test

 For the Arduino Leonardo and Micro.

 Sends a text string when a button is pressed.

 The circuit:
 * pushbutton attached from pin 4 to +5V
 * 10-kilohm resistor attached from pin 4 to ground

 created 24 Oct 2011
 modified 27 Mar 2012
 by Tom Igoe
 modified 11 Nov 2013
 by Scott Fitzgerald

 This example code is in the public domain.

 http://www.arduino.cc/en/Tutorial/KeyboardMessage
 */

#include "Keyboard.h"

const int buttonPin = 4;          // input pin for pushbutton
int previousButtonState = HIGH;   // for checking the state of a pushButton
int counter = 0;                  // button push counter

void setup() {
  // make the pushButton pin an input:
  pinMode(buttonPin, INPUT);
  // initialize control over the keyboard:
  Keyboard.begin();
}

void loop() {
  // read the pushbutton:
  int buttonState = digitalRead(buttonPin);
  // if the button state has changed,
  if ((buttonState != previousButtonState)
      // and it's currently pressed:
      && (buttonState == HIGH)) {
    // increment the button counter
    counter++;
    // type out a message
    Keyboard.print("You pressed the button ");
    Keyboard.print(counter);
    Keyboard.println(" times.");
  }
  // save the current button state for comparison next time:
  previousButtonState = buttonState;
}

Επιστροφή στην σελίδα Παραπομπές Γλώσσας

Save

Save